home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / byt87ibm.arc / SAGAN.ARC / MOUSESYS.ASM < prev   
Assembly Source File  |  1987-06-17  |  7KB  |  255 lines
  1. ; 
  2.     ASSUME CS:CSEG, DS:CSEG, ES:NOTHING, SS:NOTHING 
  3. ; 
  4. SERIAL    EQU    14H 
  5. MSDOS    EQU    21H 
  6. ; 
  7. ; 
  8. ; This is the main entry point 
  9. ; all driver routines take the function call number in BX 
  10. ; 
  11. ;     function 0 = initialize mouse 
  12. ;     function 1 = return button status 
  13. ;     function 2 = return relative motion 
  14. ;     function 3 = de-initialize mouse 
  15. ;     function 4 = return current serial port 
  16. ; 
  17. ; Normally this would be a far procedure but to avoid getting into 
  18. ; all the intricasies of loading and calling drivers I've converted 
  19. ; ENTRY to a near procedure and combined it with the sample program. 
  20. ; 
  21. ENTRY    PROC    NEAR  
  22.     CLD              ; go in the forward direction 
  23.     PUSH    DS        ; save callers segment 
  24.     PUSH    CS        ; make this segment addressable 
  25.     POP    DS 
  26.     SHL    BX,1        ; point to routine 
  27.     CALL    ROUTINES[BX]    ; and call it through table 
  28.     POP    DS        ; restore users segment 
  29.     RET            ; return far to caller 
  30. ENTRY    ENDP 
  31. ; 
  32.     DB    'Mouse systems',00    ; name 
  33. ; 
  34. ROUTINES LABEL WORD 
  35.     DW    ISERIAL        ; function 0 = initialize mouse 
  36.     DW    BUTTONSTAT    ; function 1 = return button status 
  37.     DW    MOTIONCOUNT    ; function 2 = return relative motion 
  38.     DW    DSERIAL        ; function 3 = de-initialize mouse 
  39.     DW    GSERIAL        ; function 4 = return current serial port 
  40.     DW    RETADR        ; function 5 = reserved 
  41.     DW    RETADR        ; function 6 = reserved 
  42.     DW    RETADR        ; function 7 = reserved 
  43. ; 
  44. COMNUM    DW    00        ; com# 
  45. ; 
  46. NEWX    DW    00        ; New x coordinate 
  47. NEWY    DW    00        ; New y coordinate 
  48. XACCUM    DW    0        ; Old x coordinate     
  49. YACCUM    DW    0        ; Old y coordinate 
  50. BSTAT    DB    07H        ; button status byte 
  51. CPORT    DW    03F8H        ; communications port address 
  52. PCOUNT    DB    0        ; packet counter 
  53. IMSK    DB    0EFH        ; interrupt mask 
  54. ; 
  55. ; This is the heart of the code. 
  56. ; The serial interrupt handler. This code catches serial bytes and maintains 
  57. ; a running total of delta x and delta y values. 
  58. ;  
  59. ; 
  60. ISR: 
  61.     STI            ; Ints back on 
  62.     PUSH    AX        ; Save all registers used 
  63.     PUSH    BX 
  64.     PUSH    DX 
  65.     PUSH    DS 
  66.     PUSH    CS 
  67.     POP    DS        ; make Code SEGment addressable 
  68.     MOV    DX,CPORT    ; get port address     
  69.     ADD    DX,5        ; Status  
  70.     IN    AL,DX        ; Read status 
  71.     MOV    AH,AL        ; Save in Ah 
  72.     SUB    DX,5        ; back to data port address 
  73.     IN    AL,DX        ; get byte from port 
  74.     AND    AH,01EH        ; mask error bits of status 
  75.     JNZ    ISR3        ; jmp if error 
  76. ; 
  77. ; Jump if an error has occured on the serial line! most likely an overrun
  78. ; error caused by interrupts cleared for long periods of time. 
  79. ; This will be handled simply by clearing the packet counter.  
  80. ; 
  81. ISR2: 
  82.     CMP    PCOUNT,0    ; Is this the first byte of packet ? 
  83.     JNE    ISR25        ; no so accumulate. 
  84.     MOV    AH,AL        ; it is the first byte so check certain 
  85.     AND    AH,0F8H        ; bits to se if we're in sync with the 
  86.     CMP    AH,080H        ; data stream. If we're not then 
  87.     JNZ    ISR4        ; we'll just return 
  88.     MOV    BSTAT,AL    ; we are in sync so stuff button status byte  
  89. ISR25: 
  90.     MOV    BL,PCOUNT    ; get packet counter 
  91.           INC    PCOUNT        ; increment for next serial interrupt 
  92.     OR    BL,BL        ; if it's zero we're done 
  93.     JZ    ISR4 
  94. ; 
  95.     CBW            ; Convert delta byte to delta word 
  96.     TEST    BL,1        ; Check if odd or even. odd = x values 
  97.     JZ    ADDY        ; even = y values 
  98.     ADD    XACCUM,AX    ; add to running x accumulator 
  99.     JMP    SHORT ISR29 
  100. ADDY: 
  101.     ADD    YACCUM,AX    ; or add to running y accumulator 
  102. ISR29: 
  103.           CMP    BL,4        ; end of packet  
  104.     JB    ISR4        ; no 
  105. ISR3:
  106.     MOV    PCOUNT,0    ; yes, so reset packet counter 
  107. ISR4: 
  108.     CLI 
  109.     MOV    AL,020H        ; must issue EOI 
  110.     OUT    020H,AL 
  111.     POP    DS 
  112.     POP    DX 
  113.     POP    BX 
  114.     POP    AX        ; Restore registers 
  115.     IRET            ; and return from interrupt 
  116. ; 
  117. ; This table maps button values into ones appropriate for returning 
  118. ; to application 
  119. ; 
  120. BUTMAP    DB    07,03,05,01,06,02,04,00 
  121. ; 
  122. ; This routine returns button status = ax 
  123. ; a 1 bit indicates button presses 
  124. ; 
  125. BUTTONSTAT: 
  126.     PUSH    BX 
  127.     MOV    AL,BSTAT 
  128.     AND    AX,7 
  129.     MOV    BX,OFFSET BUTMAP  ; convert to Microsoft format 
  130.     XLAT 
  131.     POP    BX 
  132. RETADR: 
  133.     RET 
  134. ; 
  135. ; Motion Count routine 
  136. ;     on entry: 
  137. ;  Ax=cursor x,Bx=cursor y (Ignored by this driver) 
  138. ;      on exit: 
  139. ;  Ax=delta  x,Bx=delta y 
  140. ; 
  141. MOTIONCOUNT: 
  142.     CALL    QREADPACKET    ; Read a packet 
  143.     MOV    BX,NEWY        ; return y coordinates 
  144.     NEG    BX        ; positive coordinate move down the screen 
  145.     MOV    AX,NEWX        ; return x 
  146.     RET 
  147. ; 
  148. ; clean up the serial port interrupts and masks 
  149. ; 
  150. DSERIAL: 
  151.     CLI 
  152.     IN    AL,021H        ; Read interupt mask             
  153.     MOV    AH,IMSK        ; clear appropriate int 
  154.     NOT    AH        ; by setting bits 
  155.     OR    AL,AH 
  156.     OUT    021H,AL        ; write it out 
  157.     MOV    DX,CPORT    ; get port address 
  158.     ADD    DX,3        ; line control register 
  159.     IN    AL,DX        ; fetch it 
  160.     AND    AL,07FH        ; set low to access interrupt  
  161.     OUT    DX,AL        ; enable register 
  162.     SUB    DX,2        ; point at interrupt enable register 
  163.     SUB    AL,AL        ; clear 
  164.     OUT    DX,AL        ; it 
  165.     ADD    DX,3        ; and clear 
  166.     OUT    DX,AL        ; modem control register 
  167.     STI            ; finished 
  168.     RET 
  169. ; 
  170. GSERIAL: 
  171.     MOV    AX,COMNUM    ; returns com# 
  172.     INC    AX 
  173.     RET 
  174. ; 
  175. ; This code intializes the mouse systems serial mouse 
  176. ; it takes the com number in Ax (1 = com1 2 = com2) 
  177. ; 
  178. ISERIAL PROC    NEAR 
  179.     PUSH    CX 
  180.     DEC    AX 
  181.     MOV    COMNUM,AX        ; Save com# 
  182.     MOV    DX,AX 
  183.     MOV    AX,087H            ; 12K BAUD 
  184.     INT    SERIAL            ; let bios initialize baud rate and stuff 
  185. ; 
  186.     PUSH    BX 
  187.     PUSH    DX 
  188.     PUSH    CS 
  189.     MOV    AX,040H            ; point at bios data segment 
  190.     MOV    DS,AX 
  191.     MOV    BX,DX 
  192.     SHL    BX,1 
  193.     MOV    DX,ZERO[BX]        ; Get port address at 40:0 or 40:2 
  194.     POP    DS 
  195.     MOV    CPORT,DX        ; save it 
  196.     CLI 
  197.     MOV    DX,OFFSET ISR        ; stick the serial interrupt handler 
  198.     MOV    AL,00CH            ; in either Int 0Ch, or 0Bh
  199.     MOV    AH,BYTE PTR COMNUM
  200.     AND    AH,1             ; only 2 Interrupts available
  201.     SUB    AL,AH
  202.     MOV    AH,025H            ; set interrupt request
  203.     INT    MSDOS 
  204. ; 
  205.     IN    AL,021H            ; mask the interrup controller 
  206.     MOV    AH,0EFH 
  207.     CMP    COMNUM,0 
  208.     JZ    ISERIAL2 
  209.     MOV    AH,0F7H 
  210. ISERIAL2: 
  211.     MOV    IMSK,AH            ; Save for later 
  212.     AND    AL,AH 
  213.     OUT    021H,AL 
  214. ; 
  215.     MOV    DX,CPORT        ; get port address 
  216.     ADD    DX,3            ; Line control register 
  217.     IN    AL,DX 
  218.     AND    AL,07FH            ; make interrupt enable register 
  219.     OUT    DX,AL            ; Addressable 
  220.     JMP    $+2            
  221.     SUB    DX,2            ; Point at it 
  222.     MOV    AL,1            ; set the data available int 
  223.     OUT    DX,AL 
  224.     ADD    DX,3             ; Modem control register 
  225.     MOV    AL,08            ; set it 
  226.     OUT    DX,AL 
  227.     STI 
  228.     MOV    DX,CPORT
  229.     IN    AL,DX            ; Clear receive buffer
  230.     POP    DX 
  231.     POP    BX 
  232.     POP    CX 
  233.     MOV    AL,-1            ; mouse available. 
  234.     RET 
  235. ISERIAL    ENDP 
  236. ;     
  237. ; 
  238. QREADPACKET: 
  239. QR1: 
  240.     CLI 
  241. ; 
  242.     NOP 
  243.     MOV    AX,XACCUM    ; get x accumulator 
  244.     MOV    NEWX,AX        ; move to new delta x 
  245.     MOV    AX,YACCUM    ; get y      
  246.     MOV    NEWY,AX        ; to new y 
  247.     SUB    BX,BX 
  248.     MOV    XACCUM,BX    ; clear  
  249.     MOV    YACCUM,BX    ; accumulators 
  250. ; 
  251.     STI 
  252. QREXIT: 
  253.     RET 
  254. ; 
  255.